;;; SPDX-License-Identifier: GPL-3.0-or-later
;;; Copyright © 2024 Joshua Hunt <joshua.edward.hunt@gmail.com>

(define-module (nongnu packages tarsnap)
  #:use-module (guix packages)
  #:use-module (guix download)
  #:use-module (guix build-system gnu)
  #:use-module (nonguix licenses)
  #:use-module (gnu packages base)
  #:use-module (gnu packages linux)
  #:use-module (gnu packages tls)
  #:use-module (gnu packages compression)
  #:use-module (gnu packages bash))

(define-public tarsnap
  (package
    (name "tarsnap")
    (version "1.0.40")
    (source
     (origin
       (method url-fetch)
       (uri (string-append
             "https://www.tarsnap.com/download/tarsnap-autoconf-" version
             ".tgz"))
       (sha256
        (base32 "1mbzq81l4my5wdhyxyma04sblr43m8p7ryycbpi6n78w1hwfbjmw"))))
    (inputs (list e2fsprogs openssl zlib))
    (native-inputs (list glibc bash))
    (arguments
     `(#:phases (modify-phases %standard-phases
                  (add-after 'unpack 'fix-get-path
                    (lambda _
                      ;; Both configure and Makefile.in use `command -p` to find
                      ;; commands using a "default" value of PATH that doesn't include
                      ;; the guix store. Removing the `-p` flag allows the scripts to
                      ;; find the commands they are trying to run.
                      (substitute* "configure"
                        (("command -p")
                         "command"))
                      (substitute* "Makefile.in"
                        (("command -p")
                         "command")))))
       ;; POSIX_SH tells the configure script where to find the `sh`
       ;; command. However, it doesn't actually seem to use the value of the
       ;; variable. Not setting this environment variable causes the configure
       ;; step to fail with an error that it can't find any POSIX-compatible
       ;; shell.
       #:configure-flags '("POSIX_SH=foo")))
    (build-system gnu-build-system)
    (synopsis
     "Tarsnap is a secure, efficient online backup service: \"Online backups
for the truly paranoid\".")
    (description
     "Tarsnap is a secure, efficient online backup service, offering
encryption, de-duplicated backups, and a pre-paid pricing model based
on actual usage.")
    (home-page "https://www.tarsnap.com/")
    (license (nonfree
              "https://raw.githubusercontent.com/Tarsnap/tarsnap/master/COPYING"))))